Make one big FAT32 partition using DOS 7.x


[ Follow Ups ] [ Post Followup ] [ Build Your Own Arcade Controls message board ] [ FAQ ]

Posted by EmuMannen on 26, 2001 at 3:39 PM:

In Reply to: Re: Majorly newbie DOS MAME question (hey! its been a LONG time since I did DOS) posted by Tehrasha on 25, 2001 at 6:16 PM:

You could use DOS 7.x to make one big partiton. Below is a batch file I made to rip DOS 7.x from any Win 9x installation... Follow instructions in the .bat file. Use FDISK to remove old partitions and make a new big one (using support for big drives). Then use FORMAT to format the new partition etc...


@echo off
rem Script file to rip most of DOS 7.x to a system diskett by EmuMannen

cls
echo.
echo Copy this script, pkzip.exe and pkunzip.exe to an _empty_
echo 1.44 mb diskett. Put the diskett in a: and run the script
echo under Windows 9x to rip most of DOS 7.x to the diskett...
echo.
pause

if %windir%! == ! goto nowin
if not exist pkzip.exe goto nozip
if not exist pkunzip.exe goto nounzip

set source=%windir%\
set target=a:
set filelist=%temp%\ripdos7x.tmp

echo %source%EMM386.EXE > %filelist%
echo %source%HIMEM.SYS >> %filelist%
echo %source%SMARTDRV.EXE >> %filelist%

set source=%source%COMMAND\

echo %source%ANSI.SYS >> %filelist%
echo %source%ATTRIB.EXE >> %filelist%
echo %source%CHKDSK.EXE >> %filelist%
echo %source%CHOICE.COM >> %filelist%
echo %source%COUNTRY.SYS >> %filelist%
echo %source%DEBUG.EXE >> %filelist%
echo %source%DELTREE.EXE >> %filelist%
echo %source%DISKCOPY.COM >> %filelist%
echo %source%DISPLAY.SYS >> %filelist%
echo %source%DOSKEY.COM >> %filelist%
echo %source%EDIT.COM >> %filelist%
echo %source%EDIT.HLP >> %filelist%
echo %source%EGA.CPI >> %filelist%
echo %source%EGA2.CPI >> %filelist%
echo %source%EGA3.CPI >> %filelist%
echo %source%FC.EXE >> %filelist%
echo %source%FDISK.EXE >> %filelist%
echo %source%FIND.EXE >> %filelist%
echo %source%FORMAT.COM >> %filelist%
echo %source%ISO.CPI >> %filelist%
echo %source%KEYB.COM >> %filelist%
echo %source%KEYBOARD.SYS >> %filelist%
echo %source%KEYBRD2.SYS >> %filelist%
echo %source%KEYBRD3.SYS >> %filelist%
echo %source%KEYBRD4.SYS >> %filelist%
echo %source%LABEL.EXE >> %filelist%
echo %source%MEM.EXE >> %filelist%
echo %source%MODE.COM >> %filelist%
echo %source%MORE.COM >> %filelist%
echo %source%MOVE.EXE >> %filelist%
echo %source%MSCDEX.EXE >> %filelist%
echo %source%NLSFUNC.EXE >> %filelist%
echo %source%SCANDISK.EXE >> %filelist%
echo %source%SCANDISK.INI >> %filelist%
echo %source%SORT.EXE >> %filelist%
echo %source%SUBST.EXE >> %filelist%
echo %source%SYS.COM >> %filelist%
echo %source%XCOPY.EXE >> %filelist%
echo %source%XCOPY32.EXE >> %filelist%
echo %source%XCOPY32.MOD >> %filelist%

echo Transfering system files...
sys c: %target%
echo Setting the RIPDOS7X diskett label...
label a:RIPDOS7X

echo Archiving DOS 7.x core files...
pkzip -b%temp% %target%DOS.ZIP @%filelist% > nul

echo Copying disk managment applications...
copy %source%ATTRIB.EXE %target% /Y
copy %source%EDIT.COM %target% /Y
copy %source%EDIT.HLP %target% /Y
copy %source%FDISK.EXE %target% /Y
copy %source%FORMAT.COM %target% /Y
copy %source%LABEL.EXE %target% /Y
copy %source%SYS.COM %target% /Y

del %filelist%
set source=
set target=
set filelist=

cls
echo.
echo Diskett in a: is now a DOS 7.x bootable system disk.
echo It also contains some disk managment applications...
echo To install DOS 7.x as the primary operating system:
echo.
echo 1. Boot from the RIPDOS7X system diskett
echo 2. Use FDISK.EXE if you need to partition the hard drive
echo 3. Use FORMAT.COM if you need to format the hard drive
echo 4. Use SYS.COM if you need to make the hard drive bootable
echo 5. Use LABEL.EXE if you need to label the hard drive
echo 6. Use PKUNZIP.EXE to unzip DOS.ZIP to \DOS on the hard drive
echo 7. Use EDIT.COM to create and edit config.sys and autoexec.bat
echo 8. Use ATTRIB.EXE and EDIT.COM if you need to edit MSDOS.SYS
echo.

goto end

:nowin
echo This script has to be executed under Windows 9x...
goto end

:nozip
echo Can't find PKZIP.EXE...
goto end

:nounzip
echo Can't find PKUNZIP.EXE...
goto end

:end





Follow Ups:



Post a Followup

Name:
E-Mail:

Subject:

Comments:

Optional Link URL:
Link Title:
Optional Image URL:


[ Follow Ups ] [ Post Followup ] [ Build Your Own Arcade Controls message board ] [ FAQ ]